cuberefract.shader

varying vec3 vEye;
varying vec3 vNormal;

void main() 
{
    // Get the normal and normalize
    vNormal = gl_NormalMatrix * gl_Normal;
    
    // Get the world space position
    vec4 vPos = gl_ModelViewMatrix * gl_Vertex;

    // Get the eye vector
    vEye = -vPos.xyz;
    
    //Use the first set of texture coordinates in the fragment shader 
    gl_TexCoord[0] = gl_MultiTexCoord0;

    // Transform the position to screen space
    gl_Position = ftransform(); 
}

~~~~~

varying vec3 vEye;
varying vec3 vNormal;

uniform float reflectivity;
uniform float refractiveindex;

// uniform sampler2D Texture0; // Diffuse map
// uniform sampler2D Texture1; // Normal map
uniform samplerCube Texture2; // Cube map
// uniform sampler2D Texture3; // Shininess map
// uniform sampler2D Texture4; // Emissive map

void main() 
{
    // Get the bump vector
    vec3 vN = normalize( vNormal );

    // Get the eye vector
    vec3 vE = normalize( vEye );
    
    // Get the reflection vector
    vec3 vReflect = reflect( vE, vN );

    // Get the refraction vector
    vec3 vRefract = refract( vE, -vN, 1.0 / refractiveindex );
    
    // Put the reflection vector through the matrix
    vReflect = mat3( gl_TextureMatrix[0] ) * vReflect;
    vReflect.x = -vReflect.x;

    // Put the refraction vector through the matrix
    vRefract = mat3( gl_TextureMatrix[0] ) * vRefract;
    vRefract.x = -vRefract.x;

    // Get the value from the cubemap for the reflection
    vec4 vReflectColour = textureCube( Texture2, vReflect.xyz );

    // Get the refraction
    vec4 vRefractColour = textureCube( Texture2, vRefract.xyz );

    // Mix the two colours based on the dot product of the eye and normal vector
    float interpolant = dot( vE, vN );
    if ( interpolant < 0.0 ) interpolant = -interpolant;

    // Reverse the interpolant and raise it to a few powers
    interpolant = pow( 1.0 - interpolant, 2.0 );

    // Set the colour
    gl_FragColor.rgb = vReflectColour.rgb * interpolant + vRefractColour.rgb * ( 1.0 - interpolant );
    
    // Set the alpha
    gl_FragColor.a = reflectivity;
}

---